描述

生成并且显示一个chart。

类别

数据输出标签, 可扩展性标签

语法

<!--- This syntax uses an XML file or string to specify the chart style. --->
<cfchart
    style = "XML string|XML filename"> 
</cfchart>

或者

<!--- This syntax uses the attributes of the cfchart tag to specify the chart style. --->
<cfchart 
    backgroundColor = "hexadecimal value|web color" 
    chartHeight = "integer number of pixels" 
    chartWidth = "integer number of pixels" 
    dataBackgroundColor = "hexadecimal value|web color" 
    font = "font name" 
    fontBold = "yes|no" 
    fontItalic = "yes|no" 
    fontSize = "font size" 
    foregroundColor = "hexadecimal value|web color" 
    format = "flash|jpg|png" 
    gridlines = "integer number of lines" 
    labelFormat = "number|currency|percent|date" 
    markerSize = "integer number of pixels" 
    name = "string"
    pieSliceStyle = "solid|sliced" 
    scaleFrom = "integer minimum value" 
    scaleTo = "integer maximum value" 
    seriesPlacement = "default|cluster| stacked|percent" 
    show3D = "yes|no" 
    showBorder = "yes|no" 
    showLegend = "yes|no" 
    showMarkers = "yes|no" 
    showXGridlines = "yes|no" 
    showYGridlines = "yes|no" 
    sortXAxis = "yes|no" 
    tipBGColor = "hexadecimal value|web color" 
    tipStyle = "MouseDown|MouseOver|none"
    title = "title of chart"
    url = "onClick destination page" 
    xAxisTitle = "title text" 
    xAxisType = "scale|category"
    xOffset = "number between -1 and 1" 
    yAxisTitle = "title text" 
    yAxisType = "scale|category"
    yOffset = "number between -1 and 1">
</cfchart>

历史

ColdFusion 8:

• 为 cfdocument里的嵌入式Flash charts提供支持。
• 为chart式样的文件添加新的属性showColumnLegend ，该属性showColumnLegend是位于charting\styles directory的一个XML文件。属性显示了每个点的入口，而且它只适用于包含一个single series的chart。showColumnLegend的值默认为true，如果想关掉这个功能，你可以修改所有chart 样式文件的设置，也可以使用一个惯例的style文件。

ColdFusion MX 7.01: 把文件改成state，这样fontSize属性就可以接受一个非整数的数字。

ColdFusion MX 7:

• 添加了样式和标题属性。
• 为 eight-digit hexadecimal值提供支持这样就可以指定 RGB颜色和透明度。
• 移除旋转属性。

ColdFusion MX 6.1:

• 添加了xAxisType和yAxisType属性。
• 改变了插值行为：这个标签现在在带有多系列的line charts上插补了数据点 。

ColdFusion MX: 添加了这个标签

属性

用途

cfchart标签定义了一个container ，在container里图会显示它的高度，宽度，背景色，标签（labels）等等。 cfchartseries标签定义了chart 的类型，包括: bar, line, pie, 等等。 cfchartdata 标签定义了一个 data point。

数据以以下方式传递给 cfchartseries 标签:

• 以 query的形式。
• 使用cfchartdata标签，以一个data points的形式。

字体类型的值是 ArialUnicodeMS以下规则适用：

• 在Windows系统里, 允许 Flash charts (type = "flash") 来 使用双字节来设定,你必须选择这个值。
• 在UNIX系统里，对于所有类型的值，要 使用双字节来设定, 你都必须选择这个值。
• 如果这个值已经选择了，那么 fontBold 和 fontItalic 属性就没有作用了。

以下的表格列出了 W3C HTML 4 ，它可以被颜色属性接受，名字叫做 color value 或者 hexadecimal 值：

对于所有其他的r color values, 你都必须输入 hexadecimal 值。你可以输入一个 six-digit 值,它指定了RGB 值,或是输入 一个eight-digit 值, 它指定了RGB 值和 and the 透明度。最先的hexadecimal 值的两个 digits指定了透明度的度数， 00 和 FF之间的值都是可用的。

更多流行浏览器支持的color names请看 www.w3.org/TR/css3-color

无论char是否缓存在内存里，无论多少chart被缓存，无论多少的chartColdFusion可以马上运行，你都可以进行具体的指定。要在 ColdFusion Administrator里进行这些设置,你可以选择Server Settings > Charting.

ColdFusion 8 让你可以在一个使用cfdocument标签的PDF 文件中嵌入Flash chart。例如:

<cfdocument format="pdf">
...
<!--- Flash chart embedded here. --->
    <cfchart format="flash" xaxistitle="Department" yaxistitie="Salary Average">
        <cfchartseries type="bar" query="DataTable" itemcolumn="Dept_Name"
            valuecolumn="avgSal">
            <cfchardata item="Facilities" value="35000">
        </cfchartseries>
    </cfchart>
</cfdocument>

例子

<!---The following example analyzes the salary data in the cfdocexamples database and
    generates a bar chart showing average salary by department. The body of the 
    cfchartseries tag includes one cfchartdata tag to include data that is not available 
    from the query. --->

<!--- Get the raw data from the database. --->
<cfquery name="GetSalaries" datasource="cfdocexamples">
    SELECT Departmt.Dept_Name, 
        Employee.Dept_ID, 
        Employee.Salary
    FROM Departmt, Employee
    WHERE Departmt.Dept_ID = Employee.Dept_ID
</cfquery>

<!--- Use a query of queries to generate a new query with --->
<!--- statistical data for each department. --->
<!--- AVG and SUM calculate statistics. --->
<!--- GROUP BY generates results for each department. --->
<cfquery dbtype = "query" name = "DataTable">
    SELECT Dept_Name,
    AVG(Salary) AS avgSal,
    SUM(Salary) AS sumSal
    FROM GetSalaries
    GROUP BY Dept_Name
</cfquery>

<!--- Reformat the generated numbers to show only thousands. --->
<cfloop index = "i" from = "1" to = "#DataTable.RecordCount#">
    <cfset DataTable.sumSal[i] = Round(DataTable.sumSal[i]/1000)*1000>
    <cfset DataTable.avgSal[i] = Round(DataTable.avgSal[i]/1000)*1000>
</cfloop>

<h1>Employee Salary Analysis</h1> 
<!--- Bar graph, from Query of Queries --->
<cfchart format="flash" 
    xaxistitle="Department" 
    yaxistitle="Salary Average"> 

<cfchartseries type="bar" 
    query="DataTable" 
    itemcolumn="Dept_Name" 
    valuecolumn="avgSal">

<cfchartdata item="Facilities" value="35000">

</cfchartseries>
</cfchart>