描述

主要用于以下操作:

• 为当前页面设定 MIME头编码类型; 如果编码信息包含了文字编码,生成该文字编码输出 .
• 发送文件内容, 或在一个变量中包含 binary data, 在页面上输出.

如果要限制这个标签, 在 ColdFusion Administrator > Security > Sandbox Security 中设定.

类别

数据输出标签

语法

<cfcontent 
    deleteFile = "yes|no"
    file = "filename"
    reset = "yes|no"
    type = "file type"
    variable = "variable name">

属性

用途

设定输出的字符编码,包含在html页面上,如下所示:

<cfcontent type="text/html; charset=ISO-8859-1">

当ColdFusion 运行一个HTTP要求的时候，它决定了HTTP response 返回的数据的字符编码。默认的方式下，ColdFusion 使用Unicode UTF-8 格式返回数据，同时它忽略页面上一个HTML meta 标签的值。你可以使用cfcontent 标签来覆盖默认的字符编码响应。举个例子来说，如果要告诉ColdFusion 返回使用了Japanese EUC 字符编码 的页面，你可以这样使用类型标签:

<cfcontent type="text/html; charset=EUC-JP"> 

如果在一个自定义标签中调用 cfcontent 标签, 而且你不想在它被其他程序或者自定义标签调用的时候让标签抛弃当前的页面，你可以设置reset = "no".

如果文件删除操作不成功, ColdFusion 会找到这个错误.

不要在一个页面的 cfflush标签后使用这个标签, 它将会没有效果或 ColdFusion 抓不到这个错误.

下面的标签可以让绝大多数的浏览器显示一个对话框提问使用者是否他们要保存用cfcontent 标签指定的文件，而cfcontent 标签使用了文件名的值指定的文件名。如果使用者选择打开文件，绝大多数的浏览器都会打开相关的程序里的文件，而不是浏览器窗口

<cfheader name="Content-Disposition" value="attachment; filename=filename.ext">

有一些文件的类型，比如说PDF 文件，不使用可执行的代码，还可用在绝大多数的浏览器上显示。为了要求浏览器直接显示文件，可以使用一个cfheader标签，代码类似如下

<cfheader name="Content-Disposition" value="inline; filename=name.ext">

你可以使用任何值作为文件名属性的filename 部分，但是文件类型的ext 部分就必须是标准 windows 扩展.

对于包含了可执行代码的文件类型，比如说Microsoft Excel 文件，绝大多数的浏览器总是在打开文件之前询问。对于这些文件类型，如果使用者选择打开文件的话，内置内容配置规格要求浏览器直接显示文件.

更多字符编码的信息,请看下面的页面信息:

• The page at www.w3.org/International/O-charset.html provides general information on character encodings and the web, and has several useful links.
• The page at www.iana.org/assignments/character-sets is a complete list of character sets names used on the Internet, maintained by the Internet Assigned Numbers Authority.
• The page at java.sun.com/j2se/1.3/docs/guide/intl/encoding.doc.html lists the character encodings that Java, and therefore ColdFusion, can interpret. This list uses Java internal names, not the IANA character encoding names that you use in the SetEncoding charset parameter and other ColdFusion attributes and parameters. ColdFusion MX 6.0 Updater 3 uses JDK 1.3. ColdFusion MX 6.1 uses JDK 1.4.2; for encoding support, see http://java.sun.com/j2se/1.4.2/docs/guide/intl/encoding.doc.html.

For a complete list of media types used on the Internet, see www.iana.org/assignments/media-types/.

范例

<!--- CFCONTENT Example 1 
This example shows the use of cfcontent to return the contents of the CF
Documentation page dynamically to the browser. You might need to change the
path and/or drive letter depending on how ColdFusion is installed on your
system. Notice that the graphics do not display and the hyperlinks do not work,
because the html page uses relative filename references.
The root of the reference is the ColdFusion page, not the location of the
html page. --->

<cfcontent type = "text/html" 
    file = "C:\CFusionMX7\wwwroot\cfdocs\dochome.htm" 
    deleteFile = "no">

<!--- CFCONTENT Example 2 
This example shows how the Reset attribute changes text output. Notice how the
first text section ("This example shows how the Reset attribute changes output
for text reset = "Yes":123) does NOT print out to the screen. --->

<p>This example shows how the Reset attribute changes output for text.</p>
<p>reset = "Yes": 123 <BR> <cfcontent type = "text/html" reset = "Yes">456</p>
<p>This example shows how the Reset attribute changes output for text.</p>
<p>reset = "No": 123 <BR> <cfcontent type = "text/html" reset = "No">456</p>
<!--- CFCONTENT Example 3 
This example triggers a download of an Excel file. The user is prompted with an option to save the file or open it in the browser. --->

<cfheader name="Content-Disposition" value="inline; filename=acmesales03.xls"> 
    <cfcontent type="application/vnd.ms-excel" file="c:\temp\acmesales03.xls">

<!--- CFCONTENT Example 4
This example triggers a download of a Word document then deletes the original from the "temp" directory. The user is prompted with an option to save the file or open it in the browser. --->

<cfheader name="Content-Disposition" value="inline; filename=temp.doc">
<cfcontent type="application/msword" file="c:\temp\Cable.doc" deletefile="yes"> 

<!--- CFCONTENT Example 5 
This example causes the browser to treat the HTML table as Excel data. 
Excel interprets the table format.
Because Excel can include executable code, the browser prompts the user whether
to save the file or open it in a browser. --->

<cfheader name="Content-Disposition" value="inline; filename=acmesalesQ1.xls">
<cfcontent type="application/vnd.msexcel">

<table border="2">
<tr><td>Month</td><td>Quantity</td><td>$ Sales</td></tr>
<tr><td>January</td><td>80</td><td >$245</td></tr>
<tr><td>February</td><td>100</td><td>$699</td></tr>
<tr><td>March</td><td>230</td><td >$2036</td></tr>
<tr><td>Total</td><td>=Sum(B2..B4)</td><td>=Sum(C2..C4)</td></tr>
</table>