描述

用CFML自定义控制标签建设一个表单。这样就比标准的HTML表单提供了更多输入元素的功能。你可以在客户端页面比如 HTML 或 Adobe Flash内容包含这些最终表单，并且通过使用XML 和 XSLT产生表单。

语法

<cfform 
    accessible = "yes|no"
    action = "form action"
    archive = "URL"
    codeBase = "URL"
    format = "HTML|Flash|XML"
    height = "pixels|percent"
    id = "HTML id"
    method = "POST|GET"
    name = "name"
    onError = "JavaScript function name or ActionScript code"
    onLoad = "load event script"
    onReset = "reset event script"
    onSubmit = "JavaScript" 
    onSuccess = "JavaScript function name" 
    preloader = "yes|no"
    preserveData = "yes|no"
    scriptSrc = "path"
    skin = "Flash skin|XSL skin"
    style = "style specification"
    timeout = "seconds"
    width = "pixels|percent"
    wMode = "window|transparent|opaque">
    
    ...

</cfform>

属性

下面的表格罗列了ColdFusion直接使用的属性。对于HTML格式的表单，这个标签也允许使用标准的 HTML form 标签，（而该标签并没有在以下清单里）并把它们直接传递给浏览器。ColdFusion也包括了XML里所有支持HTML的属性。

使用方法

这个标签要求一个结束标签。

你可以使用下列的ColdFusion表单来控制 cfform标签里的标签：

• cfapplet:只在HTML和XML的格式里使用；嵌入一个注册的Java applet程序。
• cfformgroup:只在Flash和XML格式里使用；组和排列子控件.
• cfformitem: 只在Flash和XML格式里使用；添加了水平规则，垂直规则，和表单的文本。
• cfgrid: 创建一个格控制来展示表格数据。
• cfinput: 创建一个文本输入框元素。
• cfselect: 创建一个下来列表框.
• cfslider: 只在HTML和XML格式里使用；创建一个滑动控件
• cftextarea: 创建一个多行文本输入框。
• cftree: 创建一个树型控件。

以HTML格式，所有的标签和Flash格式的cftree和cfgrid标签，都要求浏览器上支持JavaScript。cfapplet 标签和applet格式 cfgrid, cfslider, 和 cftree标签要求客户端下载一个Java applet。

如果你在cfform标签指定了Flash格式，ColdFusion会忽视表单主体里任何的HTML。你必须使用ColdFusion标签为所有的表单控件。你可以在一个HTML格式的cfform标签里包含个人的Flash格式的cfgrid和cftree控件。

以 Flash 的格式,如果你的forms没有要求敏感的数据（比如信用卡号码），就要考虑设置 timeout属性。这样可以避免用户被提示“该表单数据已过期，请在你的浏览器重装该页面”的错误，如果用户使用的浏览器返回键是返回表单的话。更多信息，请看ColdFusion Developer's Guide.的"Caching data in Flash forms" in "Caching data in Flash forms"

如果属性值文本必须包含引用标志，双写它们即可跳过。

在Flash表单里使用onErrorUsing属性

如果你使用了onSubmit或onBlur验证，如果用户试图提交一个带有有效错误的Flash表单，onError属性就会让你指定 ActionScript代码来处理。如下：

• 如果你指定了一个或者多个有效Flash表达式，Flash就会处理这些表达式。
• 如果你忽略了这个属性，Flash就会显示一个带有所有适用的错误信息的对话框。
• 如果你指定 onError="" (一个空的字符串) Flash 不会显示任何信息，但是不会提交表单。

你的ActionScript可以使用错误变量来定义域和错误。错误对象有以下的域:

下面的例子展示了用onError属性的cfform标签在accordion组件标签或包含名字域无效入口的导航标签页：

<cfform name="form1" format="flash" width="800" height="500" 
        onError="if (errors['lastName'] != undefined
            ){tabA.selectedIndex=0; _root.lastName.setFocus();}">

合并HTML表单标签和属性。

用HTML格式，cfform 标签可以让你纳入下列的标准HTML元素。他们在Flash格式里不可用。

• 标准的HTMLform标签属性和值。该属性和值都包含在form标签里，form标签在页面上 cfform输出。举个例子说，你可以像使用带有cfform的target或onMouseOver一样使用form标签属性。
• HTML标签通常是放在 HTMLform标签里。譬如说，你可以使用 HTMLinput标签在一个cfform里创建一个提交按钮，而不需要cfinput的其它功能。

  <cfform>
      <input type = "Submit" value = " update... ">
  </cfform>
  

  
  

在cfdiv, cflayout, cffpod和cfwindow控件里使用表单

e cfdiv, cflayout, cffpod和cfwindow 标签创建了基于AJAX的控件，而基于AJAX的控件可以用作互动表单的容器。当你使用这样一个结构的时候，你不可以试图让提交的表单信息促成一个新的页面来展示，相反地，你可以用动态的代码修改现存的页面，而不会导致一个完成的重载。你可以用onSuccess和onError属性来促成这个动作。

如果表单数据成功提交，用onSuccess属性指定的函数就会被调用。该函数负责更新容器，或者窗口反映提交的结果。举个例子，可以展示附加的数据或者跳出一个确认窗口。该函数不必要有任何参数。

如果一个错误发生在表单数据提交的时候，用onError属性指定的函数被调用。该函数是负责捕捉错误，比如说显示一条错误信息。该函数必须有两个参数：一个错误号码和一条错误信息。

在PDF表单纳入互动域

ColdFusion 8 让你使用cfform标签来创建包含了静态和互动的表单域的PDF表单。这个cfform标签必须存在于一个cfdocument标签内（这里format="pdf"）。只有一个cfform标签可以存在于cfdocument标签。

完成的表单可以以一个HTTP Post的形式传递给服务器，或者整个PDF可以以二进制流的形式提交。如果PDF已经提交，你可以使用cffile标签拉力保存完成的PDF表单到硬盘。

<cffile action="write" file="c:\savedpdf.pdf" output="#PDF.content#">

输出可以通过使用该标签来操纵并摘录。

只有以下的 cfform 属性支持产生PDF表单:

• action
• format
• method
• name
• onSubmit
• skin
• style

插入一个现存的用LiveCycle Designer或Acrobat产生的PDF表单，可以使用这个标签。T

范例

<h3>cfform Example</h3>
<!--- If Form.oncethrough exists, the form has been submitted. --->
<cfif IsDefined("Form.oncethrough")>
    <cfif IsDefined("Form.testVal1")>
        <h3>Results of Radio Button Test</h3>
        <cfif Form.testVal1>Your radio button answer was yes
        <cfelse>Your radio button answer was no
        </cfif>
    </cfif>
    <h3>Results of Checkbox Test</h3>
    <cfif IsDefined("Form.chkTest2")>
        Your checkbox answer was yes
    <cfelse>
        Your checkbox answer was no
    </cfif>
    <cfif IsDefined("Form.textSample") AND Form.textSample is not "">
        <h3>Results of Credit Card Input</h3>
        Your credit card number, <cfoutput>#Form.textSample#</cfoutput>, 
        was valid under the MOD 10 algorithm.
    </cfif>
    <cfif IsDefined("Form.sampleSlider")>
        <cfoutput>
            <h3>You gave this page a rating of #Form.sampleSlider#</h3>
        </cfoutput>
    </cfif>
    <hr noshade="True">
</cfif>

<!--- Begin by calling the cfform tag. --->
<cfform name="cfformexample">
    <h4>This example displays radio button input type for cfinput.</h4>
    Yes <cfinput type = "Radio" name = "TestVal1" value = "Yes" checked>
    No <cfinput type = "Radio" name = "TestVal1" value = "No">
    <h4>This example displays checkbox input type for cfinput.</h4>
    <cfinput type = "Checkbox" name = "ChkTest2" value = "Yes">
    <h4>This shows client-side validation for cfinput text boxes.</h4>
    (<i>This item is optional</i>)<br>
    Please enter a credit card number:
    <cfinput type = "Text" name = "TextSample" 
        message = "Please enter a Credit Card Number" 
        validate = "creditcard" required = "No">
    <h4>This example shows the use of the cfslider tag.</h4>
    Rate your approval of this example from 1 to 10 by sliding control.<br>
    1 <cfslider name = "sampleSlider" width="100"
            label = "Page Value: " range = "1,10"
            message = "Please enter a value from 1 to 10"> 10
    <p><cfinput type = "submit" name = "submit" value = "show me the result">
    <cfinput type = "hidden" name = "oncethrough" value = "Yes"></p>
</cfform>

一个简单的 XML form

下面的例子展示了一个简单的XML格式的表单。它使用了default.xsl转化使ColdFusion支持显示在生成的HTML输出中：

<cfform name="testXForm" format="XML" skin="basic">
<!--- Use cfformgroup to put the first and last names on a single line. --->
    <cfformgroup type="horizontal">
        <cfinput type="text" name="firstname" label="First Name:" value="Robert">
        <cfinput type="text" name="lastname" label="Last Name:" value="Smith">
</cfformgroup>
<cfinput type="password" name="password" label="Password:" value="">
<cfinput type="hidden" name="hidden" label="hidden:" value="">
<cfselect name="state" style="width:200" label="State">
    <option>California</option>
    <option selected>Utah</option>
    <option>Iowa</option>
    <option selected>New York</option>
 </cfselect>
 <cftextarea name="description" label="Description:" rows="5" cols="40">
    this is sample text.</cftextarea>
</cfform>

一个简单的 PDF form

<cfdocument format="pdf">
    <cfdocumentsection ../>
    ...
    ...
    <cfform type="html/xform">
        <cfinput type="textbox" name="employeeName" value="#fullName#" readonly="true">
        <cfinput type="textbox" name="employeeID" value="#id#" readonly>
        <cfselect name="contributionPercentage" options="#optionsStruct#" required="true">
        <cfinput type="submit" name="SubmitAsHTTPPost">
        <cfinput type="submit" name="SubmitAsPDF" submitType="PDF">
    </cfform>
    ...
    ...
    <cfdocumentsection ../>
</cfdocument>